// Simple Snake Program
// Taken from "http://timjoh.com/simple-snake-game-in-ti-basic".
// Use the j, i, l, and m to control the worm. You can only run
// into yourself three times before losing. Good luck!

) 1 1 Snakes ) 1 2 Modified\sby\sFrancois. ) 1 3 Push\sENTER\sto\sstart.

? @k ! 13 L
[

    k => @k // Store keystroke.

]

~
m @x <= 16
m @y <= 8
m @d <= 1

? @c = 0 L // Infinite loop.
[

    m @o <= Score:\s . @s
    ) 0 0 @o
    k => @k
    
    ? @k = 106
    [
    
        m @d <= 1 // Left
    
    ]
    
    ? @k = 105
    [
    
        m @d <= 2 // Up
    
    ]
    
    ? @k = 108
    [
    
        m @d <= 3 // Right
    
    ]
    
    ? @k = 109
    [
    
        m @d <= 4 // Bottom
    
    ]
    
    ? @d = 1
    [
    
        m @x <= @x - 1
    
    ]
    
    ? @d = 2
    [
    
        m @y <= @y - 1
    
    ]
    
    ? @d = 3
    [
    
        m @x <= @x + 1
    
    ]
    
    ? @d = 4
    [
    
        m @y <= @y + 1
    
    ]
    
    t @x @y => @p
    
    ? @p = * // We hit ourselves.
    [
    
        m @a <= @a + 1
        
        ? @a > 2
        [
        
            ~ .
        
        ]
    
    ]
    
    ) @x @y *
    m @s <= @s + 1 // Raise the score for survival.
    _ 100 // Wait 100 milliseconds.

]