Programming Forums - There has got to be a better way.....

Programming Forums (http://www.programmingforums.org/forumindex.php)

- JavaScript and Client-Side Browser Scripting (http://www.programmingforums.org/forum23.html)

- - There has got to be a better way..... (http://www.programmingforums.org/showthread.php?t=10925)

There has got to be a better way.....

Ok, presently this is the method I use for running an external *.exe from within a vbscript.

strComputer = "."

        Hidden_Window=5

        Set objWMIService = GetObject ("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

        set objStartup = objWMIService.Get("Win32_ProcessStartup") 

        Set objConfig = objStartup.SpawnInstance_ 

        objConfig.ShowWindow = Hidden_Window

        Set objProcess = GetObject ("winmgmts:root\cimv2:Win32_Process")

        errReturn = objProcess.Create("D:\ISRA\COSS\Filewatch.exe", null, objConfig, intProcessID)

Is there a better way to run an external *.exe from within a VBScript? I need to run it, then kill it. I search for a bit but couldn't find anything useable. Thanks in advanced.

Hi, give this a try.

<script language = "vbscript">
sub launcherSub()
dim progName
progName = "D:\ISRA\COSS\Filewatch.exe"
set oShell = createobject("wscript.shell") 'create a shell
 
'***use the line below to call your app, defined above with the "progName" variable:
oShell.run(progName)
end sub
</script>

check out this page for additonal parameters you can use with the run method. http://www.devguru.com/Technologies/...shell_Run.html

oh, and you wanted to kill the process too.

Option Explicit
Dim objWMIService, objProcess, colProcess
Dim strComputer, strProcessKill
strComputer = "."
strProcessKill = "'Filewatch.exe'"
 
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" _
& strComputer & "\root\cimv2")
 
Set colProcess = objWMIService.ExecQuery _
("Select * from Win32_Process Where Name = " & strProcessKill )
For Each objProcess in colProcess
objProcess.Terminate()
Next
 
WScript.Quit

basically it queries running processes for the desired one and terminates it.

note: I'm not sure if this is being performed on the local machine or on a remote machine, the code above is for local, if you want to kill on remote machine, check the link below.

all this code was stolen from here, i take no credit but i did test them personally and they work
http://www.computerperformance.co.uk...ocess_stop.htm